home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib15.dsk / COMMAND CHANGER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  3KB  |  57 lines
  1. 10  REM  **********************
  2. 11  REM  *   COMMAND CHANGER  *
  3. 12  REM  *  BY DONALD MILLER  *
  4. 13  REM  * COPYRIGHT (C) 1983 *
  5. 14  REM  * BY MICROSPARC, INC *
  6. 15  REM  * LINCOLN, MA. 01773 *
  7. 16  REM  **********************
  8. 20  GOSUB 440: HOME : VTAB 12: PRINT "CHANGE ERROR CODES OR COMMANDS ? (E/C) ";: GET N$
  9. 30  IF N$ = "E"  THEN 90
  10. 40  IF N$ < >"C"  THEN 20
  11. 50  IF N$ = "C"  THEN AD = 43140:B = 43272:C = 133: PRINT N$: VTAB 16: HTAB 1: INVERSE : PRINT "NO NUMBERS, PUNCTUATION MARKS OR SPACES MAY BE USED WHILE CHANGING COMMANDS"
  12. 60 A = AD
  13. 70  NORMAL 
  14. 80  FOR I = 1 TO 3500: NEXT : GOTO 100
  15. 90 AD = 43380:B = 43582:C = 202:A = AD
  16. 100 CHR =  PEEK(A):A = A +1
  17. 110 B$ =  CHR$(CHR):A$ = A$ +B$
  18. 120  IF CHR >127  THEN  GOSUB 140: IF A = B  THEN 320
  19. 130  GOTO 100
  20. 140  HOME 
  21. 150  VTAB 6: HTAB (20 -( LEN(A$)/2)): INVERSE : PRINT A$
  22. 155  VTAB 23: HTAB 10: NORMAL : PRINT "PRESS (ESC) TO QUIT": INVERSE 
  23. 160  VTAB 10: NORMAL : PRINT "IS THIS THE MESSAGE YOU WANT TO CHANGE ?": PRINT "(Y/N) ";: GET AN$
  24. 170  IF  ASC(AN$) = 27  THEN 420
  25. 180  IF AN$ < >"Y"  THEN A$ = "": RETURN 
  26. 190  VTAB 16: HTAB 1: PRINT "ENTER->";
  27. 200  INVERSE : HTAB (20 -( LEN(A$)/2)): FOR I = 1 TO  LEN(A$): PRINT " ";: NEXT 
  28. 210  VTAB 16: HTAB (20 -( LEN(A$)/2)):
  29. 220  FOR I = 1 TO  LEN(A$): GET L$: PRINT L$;:M$ = M$ +L$: NEXT 
  30. 230  NORMAL : PRINT : PRINT : PRINT "ANY CORRECTIONS ? (Y/N) ";: GET AN$
  31. 240  IF AN$ = "Y"  THEN M$ = "": HTAB 1: CALL  -868: GOTO 190
  32. 250 AC = A - LEN(M$) -1
  33. 260  FOR I = 1 TO  LEN(M$)
  34. 270 K$ =  MID$ (M$,I,1)
  35. 280  POKE (AC +I), ASC(K$)
  36. 290  NEXT 
  37. 300  POKE AC +I -1, ASC(K$) +128
  38. 310 A$ = "":M$ = "": RETURN 
  39. 320  HOME : VTAB 6: PRINT "DO YOU WANT TO CREATE A BINARY FILE TO  SAVE THESE CHANGES ?"
  40. 330  PRINT 
  41. 340  PRINT "(YOU CAN THEN <BLOAD B("N$")REWRITE> IN     HELLO PROGRAMS ALREADY ON DISK OR ->"
  42. 350  PRINT 
  43. 360  PRINT "YOU CAN <INIT> A NEW DISK NOW AND THESE CHANGES WILL BE PERMANENT)"
  44. 370  PRINT : PRINT "(Y/N) ";: GET AN$
  45. 380  IF AN$ < >"Y"  THEN 420
  46. 390  PRINT 
  47. 400  PRINT  CHR$(4);"BSAVE B("N$")REWRITE,A"AD",L"C"
  48. 410  PRINT : PRINT "DONE": FOR I = 1 TO 2000: NEXT 
  49. 420  PRINT : PRINT : PRINT "TRY AGAIN ? (Y/N) ";: GET AN$: IF AN$ = "Y"  THEN A$ = "":M$ = "": GOTO 20
  50. 430  HOME : END 
  51. 440  HOME : VTAB 6: HTAB 7: PRINT "PERSONALIZED DOS ERROR CODE"
  52. 450  VTAB 8: HTAB 18: PRINT "AND"
  53. 460  VTAB 10: HTAB 12: PRINT "COMMAND REWRITER"
  54. 470  VTAB 16: HTAB 18: PRINT "BY"
  55. 480  VTAB 18: HTAB 9: PRINT "DONALD W MILLER JR MD": VTAB 22: PRINT "*  COPYRIGHT 1983 BY MICROSPARC, INC.  *
  56. 490  FOR I = 1 TO 3500: NEXT 
  57. 500  RETURN